NodeMCU V3 ESP8266

WiFi Modes of Operation of ESP8266: There are three modes of WiFi Operation in the ESP8266 WiFi Module. Those are:

1. Station Mode (STA)
2. Soft Access Point (AP)
3. Soft AP + Station

Station Mode

Only Access Point

#include "ESP8266WiFi.h"

const char* ssid = "ChorkeOrg_2.4GHz";
const char* pass = "academia";

void setup(void) {
  pinMode(D4, OUTPUT);
  Serial.begin(115200);
  WiFi.begin(ssid, pass);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print("*");
  }

  Serial.println("");
  Serial.println("WiFi connection Successful");
  Serial.print("The IP Address of ESP8266 Module is: ");
  Serial.print(WiFi.localIP());
}

void loop() {
  digitalWrite(D4, LOW);
  delay(1000);
  digitalWrite(D4, HIGH);
  delay(1000);
}

Multi Access Point

#include <ESP8266WiFi.h>
#include <ESP8266WiFiMulti.h>

const char* ap0_ssid_50 = "ChorkeOrg";
const char* ap0_pasword = "chorke@bd/0A";
const char* ap0_ssid_24 = "ChorkeOrg_2.4GHz";

ESP8266WiFiMulti multi;

void setup(void) {
  pinMode(D4, OUTPUT);
  Serial.begin(115200);

  delay(10);
  Serial.println('\n');
  multi.addAP(ap0_ssid_24, ap0_pasword);
  multi.addAP(ap0_ssid_50, ap0_pasword);

  Serial.print("Connecting : ");
  while (multi.run() != WL_CONNECTED) {
    delay(500);
    Serial.print('>');
  }
  Serial.println('\n');
  Serial.print("Connected to: ");
  Serial.println(WiFi.SSID());
  Serial.print("IP address  : ");
  Serial.println(WiFi.localIP());
}

void loop() {
  digitalWrite(D4, LOW);
  delay(1000);
  digitalWrite(D4, HIGH);
  delay(1000);
}

Soft Access Point

#include "ESP8266WiFi.h"

const char* ssid = "ChorkeIot_2.4GHz";
const char* pass = "academia";

IPAddress local_IP(10, 10, 10, 1);
IPAddress subnet(255, 255, 255, 0);
IPAddress gateway(10, 10, 10, 1);

void setup(void) {
  pinMode(D4, OUTPUT);
  Serial.begin(115200);
  Serial.println();

  Serial.print("WNC Config: ");
  Serial.print(WiFi.softAPConfig(local_IP, gateway, subnet) ? "Ready" : "Failed!");

  Serial.println("SID Config: ");
  Serial.print(WiFi.softAP(ssid, pass) ? "Ready" : "Failed!");

  Serial.println("WAN Config: ");
  Serial.print(WiFi.softAPIP());
}

void loop() {
  digitalWrite(D4, LOW);
  delay(1000);
  digitalWrite(D4, HIGH);
  delay(1000);
}

Duel Mode

#include <ESP8266WiFi.h>
#include <ESP8266mDNS.h>
#include <ESP8266WiFiMulti.h>

const char* ssid = "ChorkeIot_2.4GHz";
const char* pass = "academia";

const char* ap0_ssid_50 = "ChorkeOrg";
const char* ap0_pasword = "chorke@bd/0A";
const char* ap0_ssid_24 = "ChorkeOrg_2.4GHz";

ESP8266WiFiMulti multi;

void setup(void) {
  pinMode(D4, OUTPUT);
  Serial.begin(115200);

  delay(10);
  Serial.println('\n');
  multi.addAP(ap0_ssid_24, ap0_pasword);
  multi.addAP(ap0_ssid_50, ap0_pasword);

  Serial.print("Connecting: ");
  while (multi.run() != WL_CONNECTED) {
    delay(500);
    Serial.print('>');
  }
  Serial.println('\n');
  Serial.print("Connected : ");
  Serial.println(WiFi.SSID());
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());

  if (MDNS.begin("esp8266")) {
    Serial.println("DNS OK!");
  }

  Serial.print("WNC Config: ");
  Serial.println(WiFi.softAPConfig(WiFi.localIP(), WiFi.gatewayIP(), WiFi.subnetMask()) ? "Ready" : "Failed!");

  Serial.print("SID Config: ");
  Serial.println(WiFi.softAP(ssid, pass) ? "Ready" : "Failed!");

  Serial.print("WAN Config: ");
  Serial.println(WiFi.softAPIP());
}

void loop() {
  digitalWrite(D4, LOW);
  delay(1000);
  digitalWrite(D4, HIGH);
  delay(1000);
}

Web Server

#include <WiFiClient.h>
#include <ESP8266WiFi.h>
#include <ESP8266mDNS.h>
#include <ESP8266WiFiMulti.h>
#include <ESP8266WebServer.h>

const char* ssid = "ChorkeIot_2.4GHz";
const char* pass = "academia";

const char* ap0_ssid_50 = "ChorkeOrg";
const char* ap0_pasword = "chorke@bd/0A";
const char* ap0_ssid_24 = "ChorkeOrg_2.4GHz";

ESP8266WiFiMulti multi;
ESP8266WebServer server(80);

void handleRoot();
void handleNotFound();

void setup(void) {
  pinMode(D4, OUTPUT);
  Serial.begin(115200);

  delay(10);
  Serial.println('\n');
  multi.addAP(ap0_ssid_24, ap0_pasword);
  multi.addAP(ap0_ssid_50, ap0_pasword);

  Serial.print("Connecting: ");
  while (multi.run() != WL_CONNECTED) {
    delay(500);
    Serial.print('>');
  }
  Serial.println('\n');
  Serial.print("Connected : ");
  Serial.println(WiFi.SSID());
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());

  if (MDNS.begin("esp8266")) {
    Serial.println("DNS OK!");
  }

  server.on("/", handleRoot);
  server.onNotFound(handleNotFound);
  server.begin();
  Serial.println("HTTP server started");

  Serial.print("WNC Config: ");
  Serial.println(WiFi.softAPConfig(WiFi.localIP(), WiFi.gatewayIP(), WiFi.subnetMask()) ? "Ready" : "Failed!");

  Serial.print("SID Config: ");
  Serial.println(WiFi.softAP(ssid, pass) ? "Ready" : "Failed!");

  Serial.print("WAN Config: ");
  Serial.println(WiFi.softAPIP());
}

void loop() {
  server.handleClient();
  digitalWrite(D4, LOW);
  delay(1000);
  digitalWrite(D4, HIGH);
  delay(1000);
}

void handleRoot() {
  server.send(200, "text/plain", "Hello, Acadmeian!");
}

void handleNotFound() {
  server.send(404, "text/plain", "404: Not found");
}

Font Controller

FontCtrl.hpp

#ifndef __FontCtrl_hpp__
#define __FontCtrl_hpp__

#include <Arduino.h>
#include <ESP8266WiFi.h>
#include <ESP8266mDNS.h>
#include <ESP8266WebServer.h>

class FontCtrl: public RequestHandler {
public:
  FontCtrl(const char *uri = "about"): _uri(uri) {}
  bool handle(ESP8266WebServer&, HTTPMethod, String) override;
  bool canHandle(HTTPMethod, String) override;
protected:
  String _uri;
};
#endif // __FontCtrl_hpp__

FontCtrl.cpp

#include "FontCtrl.hpp"

bool FontCtrl::canHandle(HTTPMethod method, String uri) {
    if (method != HTTP_GET || uri != _uri) {
        return false;
    }
    return true;
}

bool FontCtrl::handle(ESP8266WebServer &server, HTTPMethod requestMethod, String requestUri) {
    if (!canHandle(requestMethod, requestUri)){
        return false;
    }
    server.send(200, "text/plain", "Hello, Acadmeian!");
    return true;
}

#include "FontCtrl.hpp"
//...

void setup(void) {
  //...
  server.addHandler(new FontCtrl("/"));
  Serial.begin(115200);
  //...
}

Libraries

cd ~/Documents/Arduino/libraries;\
git clone https://github.com/me-no-dev/ESPAsyncTCP.git;\
git clone https://github.com/me-no-dev/ESPAsyncWebServer.git;\
git clone https://github.com/bblanchon/ArduinoJson.git;\
cd ArduinoJson; git checkout v5.13.5; cd ..

Tools

File System Uploader

cd ~/Documents/Arduino; mkdir tools; cd tools

wget https://github.com/esp8266/arduino-esp8266fs-plugin/releases/download/0.5.0/ESP8266FS-0.5.0.zip
unzip ESP8266FS-0.5.0.zip;rm -rf ESP8266FS-0.5.0.zip 

wget https://github.com/me-no-dev/arduino-esp32fs-plugin/releases/download/1.0/ESP32FS-1.0.zip
unzip ESP32FS-1.0.zip; rm -rf ESP32FS-1.0.zip

# compressing the static assets for node mcu v3 gzip CKi.js gzip -c CKi.js > CKi.js.gz

# decompressing the static assets of node mcu v3 gzip -d CKi.js.gz gunzip CKi.js.gz

AsyncWebServer

Path Variable

# windows
echo 'compiler.cpp.extra_flags=-DDASYNCWEBSERVER_REGEX' \
>> ~/AppData/Local/Arduino15/packages/esp8266/hardware/esp8266/2.6.3/platform.local.txt

# macos
echo 'compiler.cpp.extra_flags=-DDASYNCWEBSERVER_REGEX' \
>> ~/Library/Arduino15/packages/esp8266/hardware/esp8266/2.6.3/platform.local.txt

# linux
echo 'compiler.cpp.extra_flags=-DDASYNCWEBSERVER_REGEX' \
>> ~/.arduino15/packages/esp8266/hardware/esp8266/2.6.3/platform.local.txt

References

Quick Start with NodeMCU V3 ESP8266 WiFi Modes Station Access Point Blynk Simple ESP8266 Header Arduino core for ESP8266 Connect ESP8266 to WiFi NodeMCU V3 ESP8266 Soft Access Point Class Blynk C++ Library Blynk Example Arduino IDE

Decoding and Encoding JSON with Arduino Client-Server Wi-Fi Communication Arduino Hacking Libraries Arduino Client for MQTT ESB8266WiFi.h WiFi Connections Web Socket & FS Arduino Package Ardunio CLI NTP

Arduino ESP8266 File System Uploader Arduino ESP32 File System Uploader Where should I need to put Enums WebServer Custom Handler Handle Page Not Found SPI Flash File System ESP8266WebServer Pass By Reference WiFi Client Server File System

---

ArduinoJson Create Nested Object ESPAsyncMQTTClient ESPAsyncWebServer GZip Command Alias of a Class ESPAsyncTCP Smart Home ArduinoJson JsonObject JsonArray

AsyncMqttClient Example for ESP8266 SPIFFS: File System Object ArduinoJson Releases Serve Static by GZIP Mime Table Header